//|OCG|=gLiTcH=

main() 
{ 

	precachemodel("xmodel/v_us_air_p47");
	level thread Random_Plane_FlyBy(); 
}

#using_animtree ("stuka");
Random_Plane_FlyBy()
{
	path_start = [];
	path_end = [];
	path_start[0] = (-4038, 1712, 1332);
	path_end[0] = (1354, -4233, 1171);
	path_snd_delay[0] = 1;
	path_start[1] = (-4, 2144, 1216);
	path_end[1] = (-4269, -4234, 1496);
	path_snd_delay[1] = 0;

//Time = Distance / Speed
//
//Distance = Time * Speed
//
//Speed = Distance / Time
	wait (45 + randomint(45));

	level.plane_flybys = 1;
	while(1)
	{
		// Choose Random Path
		random_path = randomint(path_start.size);
		the_path_start = path_start[random_path];
		the_path_end = path_end[random_path];

		side = randomint(2);

		if(side == 1)
		{
			startpos = the_path_start;
			endpos = the_path_end;
		}
		else
		{
			startpos = the_path_end;
			endpos = the_path_start;
		}

		sound_delay = path_snd_delay[random_path];

		speed = (1050  + randomint(500));
		dist = distance(startpos,endpos);
	
		time = (dist / speed);

		num_of_planes = 1 + randomint(2);
		println("num_of_planes ", num_of_planes);
		for(i=0;i<num_of_planes;i++)
		{
			level.plane_flybys--;
			random_x = (startpos[0] - 512) + randomfloat(512);
			random_y = (startpos[1] - 512) + randomfloat(512);
			random_z = (startpos[2] - 64) + randomfloat(512);
			offset = (random_x, random_y, random_z);

//			println("OFFSET = ",offset);

			plane = spawn("script_model", offset);
			plane setmodel("xmodel/v_us_air_p47");
			plane thread Plane_Move(startpos,endpos,time, sound_delay);
			wait (0.5 + randomfloat(2));
		}

//		println("PLANE GROUPS : ",level.plane_flybys);

		while(level.plane_flybys <= 0)
		{
			wait 1;
		}

		wait (45 + randomint(45));
	}
}

do_line()
{
	self endon("death");
	while(1)
	{
		line(self.origin, (0,0,0),(1,1,1));
		print3d((self.origin + (0,0,50)), self.angles, (1,1,1));
		wait 0.05;
	}
}

Plane_Move(startpos,endpos,time, sound_delay)
{
	self moveto(endpos, time, 0, 0);
	self.angles = vectortoangles (endpos - startpos);
	self thread Plane_Rotate();
	level thread Plane_Sound(sound_delay);

	self waittill("movedone");
	level.plane_flybys++;
	
	println("Deleting plane.");
	self delete();
}

Plane_Rotate()
{
	self endon("death");
	og_angles = self.angles;

	while(1)
	{
		random_x = og_angles[2] + (-45 + randomfloat(30));
		random_y = og_angles[0] + (-5 + randomfloat(10));
		random_time = 2 + randomfloat(5);
		offset = (random_y, og_angles[1], random_x);

		self rotateto(offset, random_time, 0.5, 0.5);
		self waittill("rotatedone");
	}
}

Plane_Sound(sound_delay)
{
	org = spawn("script_model",(-1601,-1101,1801));
	
	org SetContents(0);
	wait 0.1;
	random_num = randomint(2);
	if(random_num == 0)
	{
		alias = "bf109_attack03";
		sound_wait = .1;
	}
	else
	{
		alias = "bf109_attack04";
		sound_wait = .2;
	}

	//if(isdefined(sound_delay))
	//{
	//	wait sound_delay;
	//}

	println("^5Playing Sound " + alias + " wait: " + sound_wait);
	org playsound (alias);
	wait sound_wait;
	println("DELETE!");
	org delete();
}

do_line2()
{
	self endon("death");
	while(1)
	{
		line(self.origin, (self.origin + (0,0,1000)),(1,0,0));
		wait 0.05;
	}
}