ok so im trying to make something pick a random player and move them to the other team after 45 seconds have passed when the game starts but im having trouble doing it so i had a look in the _teams.gsc and tried making it but it just isnt getting through to me how i would do it. this is what i did.

   

 playerres()
{
p = getEntArray( "player", "classname" );


for(i=0;i<p.size;i++)
{
if(p[i].sessionstate != "spectating")
	{
	p[i].switching_teams = true;
	p[i].joining_team = "axis";
	p[i].leaving_team = "allies";
	p[i].sessionteam = "axis";
	p[i].pers["team"] = "axis";
	p[i].team = "axis";
	p[i].cur_kill_streak = 0;
	p[i] maps\mp\gametypes\_globallogic::spawnplayer();
	
	thread pickRandom();
	}

	}	

}


pickRandom()
{
p = getEntArray( "player", "classname" );

rand = randomInt(p.size);
if(p[rand].sessionstate == "playing")
	{
wait 45;
	p[rand] suicide();
	}
else
	thread pickRandom();
}       

Try this (untested):

start()		
{
	candidateteam = self.pers["team"];
	
	if( candidateteam != "allies" && candidateteam != "axis" )
		return;
	
	level thread SelectCandidate( candidateteam, 45 );
}

SelectCandidate( team, delay )
{
	wait delay;
	
	candidate = undefined;
	candidate_credit = 0;

	for( ;; )
	{
		players = level.players;

		// Increase randomly the credit of all living players of the team
		for (i = 0; i < players.size; i ++)
		{
			player = players[i];
		
			if( !isdefined( player.pers["team"] ) || player.pers["team"] != team )
				continue;

			if( !isdefined( player.move_credit ) )
				player.self_credit = 0;
		
			if( player.sessionstate == "playing" )
				player.move_credit += randomInt( players.size );
		}
	
		// Choose the new move candidate = the alive player with the highest credit
		for(i = 0; i < players.size; i ++)
		{
			player = players[i];
		
			if( !isdefined( player.pers["team"] ) || player.pers["team"] != team )
				continue;
		
			if( player.move_credit > candidate_credit )
			{
				candidate = player;
				candidate_credit = player.move_credit;
			}
		}

		if( isdefined( candidate ) && candidate.sessionstate == "playing" )
			break;
		
		wait 1;
	}
	
	newTeam = undefined;

	if( candidate.pers["team"] == "axis" ) 
		newTeam = "allies";
	else if( candidate.pers["team"] == "allies" ) 
		newTeam = "axis";

	candidate.pers["team"] = newTeam;
	if(candidate.pers["team"] == "allies")
		candidate thread switchteams( "allies" );
	else
		candidate thread switchteams( "axis" );
	
}

switchteams( Team )
{

	if(self.sessionstate != "dead")
	{
		self.switching_teams = true;
		self.joining_team = Team;
		self.leaving_team = self.pers["team"];
		self suicide();
	}
	
	self.pers["lockteams"] = true;
	self.pers["team"] = Team;
	self.team = Team;
	self.pers["teamTime"] = undefined;
	self.sessionteam = self.pers["team"];
	self maps\mp\gametypes\_globallogic::updateObjectiveText();
	
	self maps\mp\gametypes\_spectating::setSpectatePermissions();
	
	self notify( "end_respawn" );
}

edited on Apr. 7, 2010 09:29 am by DemonSeed

edited on Apr. 7, 2010 09:34 am by DemonSeed

i fixed the other error and now get this saying when 45 seconds is up and it switches whole team not just one player

cannot cast undefined bool

pair 'undefined' and '1' has unmatching types 'undefined and 'int'
player.move_credit += randomint( player.size );

Right, this works because I tested it:

onStartGameType()
{

	level thread SelectCandidate( randomizeTeam(), 45 );
}

randomizeTeam()
{
	team = [];
	team[0] = "allies";
	team[1] = "axis";
	
	string = team[ randomint( team.size ) ];
	return string;	

}
	
SelectCandidate( team, delay )
{
	wait delay;
	
	candidate = undefined;
	candidate_credit = 0;

	for( ;; )
	{
		players = level.players;

		// Increase randomly the credit of all living players of the team
		for (i = 0; i < players.size; i ++)
		{
			player = players[i];
		
			if( !isdefined( player.pers["team"] ) || player.pers["team"] != team )
				continue;

			if( !isdefined( player.move_credit ) )
				player.move_credit = 0;
		
			if( player.sessionstate == "playing" )
				player.move_credit += randomInt( 100 );
		}
	
		// Choose the new move candidate = the alive player with the highest credit
		for(i = 0; i < players.size; i ++)
		{
			player = players[i];
		
			if( !isdefined( player.pers["team"] ) || player.pers["team"] != team )
				continue;
		
			if( player.move_credit > candidate_credit )
			{
				candidate = player;
				candidate_credit = player.move_credit;
			}
		}

		if( isdefined( candidate ) && candidate.sessionstate == "playing" )
			break;
		
		wait 1;
	}
	
	newTeam = undefined;

	if( candidate.pers["team"] == "axis" ) 
		newTeam = "allies";
	else if( candidate.pers["team"] == "allies" ) 
		newTeam = "axis";

	candidate.pers["team"] = newTeam;
	if(candidate.pers["team"] == "allies")
		candidate thread switchteams( "allies" );
	else
		candidate thread switchteams( "axis" );
	
}

switchteams( Team )
{

	if(self.sessionstate != "dead")
	{
		self.switching_teams = true;
		self.joining_team = Team;
		self.leaving_team = self.pers["team"];
		self suicide();
	}
	
	self.pers["lockteams"] = true;
	self.pers["team"] = Team;
	self.team = Team;
	self.pers["teamTime"] = undefined;
	self.sessionteam = self.pers["team"];
	self maps\mp\gametypes\_globallogic::updateObjectiveText();
	
	self maps\mp\gametypes\_spectating::setSpectatePermissions();
	
	self notify( "end_respawn" );
}

The onStartGameType() function is Callback_StartGametype() - it must be started from there.

edited on Apr. 7, 2010 10:22 am by DemonSeed

i didnt really understand where to put it so this goes in the globallogic under callback_startgametype?

edit: Nevermind I got it working. Thanks DemonSeed


edited on Apr. 7, 2010 10:49 am by liamo7

liamo7 writes...

Well, yes - the first thread has to start in the callback_startgametype() function, but _globallogic.gsc isnt the only GSC file with that function in it. There is also _callbacksetup.gsc, which is where the "real" codecallbacks are made.

the rest of the functions can go in any GSC file you want - custom or otherwise. Just make sure you thread to where ever they are properly.