Information
This will show you how to put buyable ammo in your map, allowing players to buy ammo for any weapon they are holding.

Radiant
Open your map in Radiant and put a trigger_use where you want to have the buyable ammo at. Then, give it these KVPs:

"targetname" "give_ammo"
"zombie_cost" "1500"
"hintstring" "Press [Use] to buy ammo [Cost: 1500]"

NOTE: You may also set the cost to what you want. Just be sure to modify the hint string.

Save the map and close Radiant.

GSC
Open yourmap.gsc (raw\maps) and put this in the init_nazi_zombie_ver_ex() function:

ammo_trigs = getentarray("give_ammo","targetname");
array_thread(ammo_trigs,::give_ammo);

Then, create a new function:

give_ammo()
{
	while(1)
	{
		wait(0.05);

		// variables
		who = undefined;

		self SetCursorHint( "HINT_ACTIVATE" );
		self UseTriggerRequireLookAt();
		self waittill("trigger", who);

		weapon = who GetCurrentWeapon();
		ammocount = who getammocount(weapon);
		clipcount = who getweaponammoclip(weapon);
		maxammo = weaponmaxammo(weapon);
      
		if( !is_player_valid( who ) || maxammo <= ammocount + clipcount) continue;
   
		give = 0;

		if ( weapon != "fraggrenade" && weapon!= "stielhandgranate" && weapon != "molotov" && weapon != "mine_bouncing_betty")
		{
			if( who.score > self.zombie_cost )
			{
				give = 1;
			}
			else
			{
				give = 0;
			}
		}

		if( give > 0 )
		{
			who givemaxammo( who GetCurrentWeapon() );
			who maps\_zombiemode_score::minus_to_player_score( self.zombie_cost );
			who playsound( "cha_ching" );
		}      
		else
		{
			who playsound( "no_cha_ching" );
		}
	}   
}

Save and close.

Credits
[HOG]Rampage
Jacmac
customcod.com
modsonline.com
[SSG]Titan*BK*




edited on May. 20, 2009 03:01 pm by Sgt.Rampage

edited on May. 20, 2009 03:02 pm by Sgt.Rampage

I have made something just like this. However, mine would give you ammo, just as if you got a max ammo, but just for you. I also had it randomly give it a new cost each time it was used. Nice job :)