Hey guys. I'm trying to set up a working artillery system, that randomly plays an explosion effect on one of the script_origins with the targetname "artilleryspot" (random one in the array). I want this to work to fire like 30 - 40 shells every artillery barrage but when I try my script nothing happens.

level._effect["flak_artillery"] =  loadfx("fx/explosions/artilleryExp_dirt_libya.efx");
artillery_spots = getentarray("artilleryspot","targetname");
for(i=0;i>30;i++) { // play fx 30 times
wait(1);
rand = randomint(artillery_spots.size);
fx_origin = artillery_spots[rand] getorigin();
playfx(level._effect["flak_artillery"], fx_origin);
}

This is for sp. Can anyone tell me what's wrong?

edited on Aug. 4, 2007 07:04 am by XICXAC

try

for(i=0;i<30;i++)

instead.

omg... that easy? aja it worked.. thx

i also wanna make a ramdom artillery system ... can you maybe send the hole code and what i have to make in radiant .... thx

I tryied do a script on artillery - randomly plays efx and do radius damage in origin ( still without making holes - but it won't be difficult)

mainly used script on making mortal holes

main()
{
level._effect["mortexplosion"] = loadfx("fx/explosions/artilleryExp_dirt_brown.efx");

thread bradio();
level.bombing = false;

}

bradio()
{
bradio=getent("bradio","targetname");
trig=getent("bradiotrig","targetname");

 while(1)
 {
 trig waittill ("trigger",other);

 if((isplayer (other)) && (other.pers["team"] == "allies") && !level.bombing)
 {
 level.bombing = true;
 bradio playsound("sound1sg");
 wait 5;
 bradio playsound("sound3sg");
 wait 5;
 thread bombing();
 }
 }
}

bombing()
{
 orig_boom = getentarray ("orig_boom","targetname");
 for(i=0;i<10;i=i+1)
 {
 k=randomint(31); //nums of origins on map + 1

 origin = orig_boom[k] getorigin();
 
 orig_boom[k] playsound("incoming_mortar");
 wait (1);

 orig_boom[k] playsound("explosion_ground");
 playfx(level._effect["mortexplosion"], origin);
 radiusDamage(origin, 200, 200, 100);

 wait (1);

 }
level.bombing = false;
}

what i have to make in radient?

add some trigger , brushmodel for speaker and planty of origins with same targetname (but change line k=randomint to fit you)

Well here's my code. Before you add it to your source code, make a bunch of script_origins, all with the key/value of targetname/artilleryspot .

Now I made this an own function so you have to call it to get it working. In your code, write

thread artillery(10)

or

artillery(10)

The "10" means it will "fire" 10 shells.
you also need to add the main artillery function

artillery(shells) {
	artillery_spots = getentarray("artilleryspot","targetname");

	for(i=0;i<shells;i++) {
		wait(0.5 + randomfloat(1));
		rand = randomint(artillery_spots.size);

		origin = artillery_spots[rand] getorigin();
		playfx(level._effect["flak_artillery"], origin);
		if(distance(artillery_spots[rand].origin,level.player.origin) > 100) {
			level.player playsound("explosion_ground");
			earthquake(0.5, 2, level.player.origin, distance(artillery_spots[rand].origin,level.player.origin));
		}
	}
	}

The earthquake is just something i played with, and as I can't get the sounds working, there are no sounds played in this script. You gonna have to add that yourself.

srry for using this topic but i have a question about the same subject.

i also want a artillery system. But this time i want to trigger it. so when the player hits the trigger the artillery must start.

i have made the origins and used the script of XICXAC and that works perfect (no sound yet but working on that) . only the artillery starts when the map starts.

now i made a trigger named:

Key: targetname
value: startartillery


And i use this code but i doens't work.

artillery()
{
	startartillery = getent ("startartillery", "targetname");
	trig = getent ("startartillery_trigger", "targetname");
	
	{
	trig waittill ("trigger");
	
	level._effect["flak_artillery"] =  loadfx("fx/explosions/artilleryExp_dirt_libya.efx");
	artillery_spots = getentarray("artilleryspot","targetname");
	for(i=0;i<30;i++) { // play fx 30 times
	wait(1);
	rand = randomint(artillery_spots.size);
	fx_origin = artillery_spots[rand] getorigin();
	playfx(level._effect["flak_artillery"], fx_origin);
	}
	}
}

Try

artillery()
{
	startartillery = getent ("startartillery", "targetname");
	
	{
	startartillery waittill ("trigger");
	
	level._effect["flak_artillery"] =  loadfx("fx/explosions/artilleryExp_dirt_libya.efx");
	artillery_spots = getentarray("artilleryspot","targetname");
	for(i=0;i<30;i++) { // play fx 30 times
	wait(1);
	rand = randomint(artillery_spots.size);
	fx_origin = artillery_spots[rand] getorigin();
	playfx(level._effect["flak_artillery"], fx_origin);
	}
	}
}