Oh ok thanks flesym now i understand it!!!!!
thanks again well se wat happens again

well i did it
key:targetname
value:weapons


Got this error

******* script runtime error *******
array is not a field object: (file 'maps/mp/mp_how.gsc', line 14)
if(!isdefined(weapons.script_timescale))
*
called from:
(file 'maps/mp/mp_how.gsc', line 4)
WeaponRespawner("weapons", 5);
*
started from:
(file 'maps/mp/mp_how.gsc', line 1)
main()
*
************************************
dont know but it isnt liking wat i put in

When I pasted the code into the forum the array brackets got removed for some reason. Instead of having the following two lines in the code:

if(!isdefined(weapons[i].script_timescale))
weapons[i].script_timescale = defaultrespawndelay;
...
weapons[i] thread weapon_think(weapons.script_timescale);

it got turned into the folliwing lines without the [ i ] part since the forum though that the bracket i part was for formating as italics,:

if(!isdefined(weapons.script_timescale))
  weapons.script_timescale = defaultrespawndelay;
...
weapons thread weapon_think(weapons.script_timescale);

Here is the script corrected without the eliminated array reference:

main()
{
  maps\mp\_load::main();
  WeaponRespawner("weapons", 5);
}

WeaponRespawner(targetname, defaultrespawndelay)
{
weapons = getentarray(targetname, "targetname");
if(weapons.size > 0)
{
for(i=0; i < weapons.size; i++) 
{
if(!isdefined(weapons[i].script_timescale))
weapons[i].script_timescale = defaultrespawndelay;

// kick off a thread to listen for when the item gets picked up
weapons[i] thread weapon_think(weapons.script_timescale);
}
}
}

// self = weapon reference
weapon_think(delaytime)
{
// capture important weapon data first to allow us to respawn them
classname = self.classname;
model = self.model;
count = self.count;
org = self.origin;
angles = self.angles;

targetname = self.targetname;

// Wait till the weapon gets picked up
self waittill("trigger");

// Wait the delay before respawn
wait delaytime;

// respawn the weapon
weapon = spawn(classname, org);
weapon.angles = angles;
weapon.count = count;
weapon setmodel(model); 
weapon.script_timescale = delaytime;
weapon.targetname = targetname;

// Kick off a new thread with the new weapon and kill the old one
weapon thread weapon_think(delaytime);
}

edited on Jul. 1, 2006 04:21 pm by sentchy

is the array necessary?

i got this error

******* script runtime error *******
array is not a field object: (file 'maps/mp/mp_how.gsc', line 18)
weapons thread weapon_think(weapons.script_timescale);
*
called from:
(file 'maps/mp/mp_how.gsc', line 4)
WeaponRespawner("weapons", 5);
*
started from:
(file 'maps/mp/mp_how.gsc', line 1)
main()
*
************************************
just a diffirent line im not sure wat is wrong hmm
i dont really know scripts other wise i could probebly figure this out jeesh it doesnt like something when i call it up from radient

edited on Jul. 1, 2006 09:28 pm by Sweemanz

Got to the line in error and add the [ i ] part that is missing:

Change

weapons thread weapon_think(weapons.script_timescale);

to

weapons[i] thread weapon_think(weapons[i].script_timescale);

You need the array if you want to have more than one weapon that can respawns.

The complete correct code is:

main()
{
  maps\mp\_load::main();
  WeaponRespawner("weapons", 5);
}

WeaponRespawner(targetname, defaultrespawndelay)
{
weapons = getentarray(targetname, "targetname");
if(weapons.size > 0)
{
for(i=0; i < weapons.size; i++) 
{
if(!isdefined(weapons[i].script_timescale))
weapons[i].script_timescale = defaultrespawndelay;

// kick off a thread to listen for when the item gets picked up
weapons[i] thread weapon_think(weapons[i].script_timescale);
}
}
}

// self = weapon reference
weapon_think(delaytime)
{
// capture important weapon data first to allow us to respawn them
classname = self.classname;
model = self.model;
count = self.count;
org = self.origin;
angles = self.angles;

targetname = self.targetname;

// Wait till the weapon gets picked up
self waittill("trigger");

// Wait the delay before respawn
wait delaytime;

// respawn the weapon
weapon = spawn(classname, org);
weapon.angles = angles;
weapon.count = count;
weapon setmodel(model); 
weapon.script_timescale = delaytime;
weapon.targetname = targetname;

// Kick off a new thread with the new weapon and kill the old one
weapon thread weapon_think(delaytime);
}

edited on Jul. 1, 2006 10:12 pm by sentchy

WOOOOOOOOOOOOT U ROCK DUDE IT WORKED FINALLY!!!!!!!!!!
WAAAAAAAAAAAHOOOOOOOOO
thanks a heap dude
i owe u Three!!!

Great, your welcome!

Next time I am more carefully with pasting code and making sure to use the protecting "code" button.

Cheers!

it works real well. excellent job.

Sentchy...you script god!!! I'll come running to ya when i need script help....

Not a script god =p

I just have stopped coding for real a few years ago when I climbed the management ladder to high. Now I miss the coding and COD2 is such a fun outlet to code a little again. Even with its shortcomings the COD2 engine is so exciting to me with how easy you can create your own game. Before script engines this would have been days of coding and not an hour or so.