Hi mappers,

I just want to learn to make animated ais and i saw a very good, and special anim in the The Coup sp mission. When we in the car and we drive in a narrow street there is a dumpster in the left side of the street and in it, there is az arabic man who is hiding. Somebody can help me in it?

Regards, Stanley.

edited on Nov. 11, 2012 03:58 am by wastanley

Radiant:

1/ Place a "script_model" in your map. Give it these values.

model me_dumpster_anim
targetname dumpster

2/ Place an AI actor in your map. Stand him right in dumpster. Give it these values.

targetname civilian

3/ Place a "trigger_once" in your map. This will trigger the animation. Give it these values.

targetname dumpster_trig

Scripting:

In YOURMAPNAME.gsc where YOURMAPNAME is the name of your .gsc script. You need.


#include maps\_utility;
#include common_scripts\utility;
#include maps\_anim;

#using_animtree( "generic_human" );
main()
{
maps\YOURMAPNAME_anim::main();
maps\_load::main();
thread dumpsterhide();
}

dumpsterhide()
{
dumpster_trigger = getent("dumpster_trig","targetname");
dumpster_trigger waittill("trigger");
dumpster = getent( "dumpster", "targetname" );
dumpster.animname = "dumpster";
dumpster assign_animtree();

civilian = getent( "civilian", "targetname");
civilian.animname = "human";
civilian teleport ( ( dumpster.origin ));
civilian RemoveDroneWeapon();

civilian thread anim_single_solo( civilian, "dumpster_open" );
dumpster anim_single_solo( dumpster, "dumpster_open" );
civilian delete();
}

removeDroneWeapon()
{
size = self getattachsize();
for ( i = 0;i < size;i++ )
{
tag = self getattachtagname( i );
if ( tag == "tag_weapon_right" )
{
model = self getattachmodelname( i );
self Detach( model, tag );
}
}
}

In YOURMAPNAME_anim.gsc You need.

#include common_scripts\utility;
#include maps\_utility;
#include maps\_anim;


main()
{
anim_human();
anim_dumpster();
}




#using_animtree( "generic_human" );

anim_human()
{
level.scr_animtree[ "human" ] = #animtree;
level.scr_anim[ "human" ][ "dumpster_open" ] = %coup_dumpster_man;
}

#using_animtree( "script_model" );
anim_dumpster()
{
level.scr_animtree[ "dumpster" ] = #animtree;
level.scr_anim[ "dumpster" ][ "dumpster_open" ] = %coup_dumpster_lid;
}

In your Zone file you need to add.

xanim,coup_dumpster_man
xanim,coup_dumpster_lid

edited on Nov. 10, 2012 05:27 pm by MODDER_BC

NOTE: You can do alot more like have him run around a corner first. But this will get you started.

Thank you so much! I owe you one.

No sweat, I dont mind helping out fellow mappers/scripters.

Is there any way to use the animations in an mp map not just in an sp map?

i doubt it as the AI is an SP feature in cod4.