Hey!

Is it possible to bend a trajectory of a brush model to a script origine,or connect 4 or 5 script origine to change the way of the object with a curved trajectory?

Thx!

Quadratic Bezier curves between point A and B, then B to C and so on.

Hi and thanks, but what is "Quadratic Beziert"?...

create an array with:
the first entry as your starting point
the last entry as your target point
the entries between as your curve point (act like 'hinges' to create the curve)

call a loop to move your object to to your target end let the code recalculate your next target to call moveTo() on

/*=============
Name: curve( <posArray> , <fraction> )
Summary: Returns a smooth curve between the first and the last point in the posArray, directed by the points in between them.
CallOn: none
required Arg: <posArray>: An array including the starting point as first value, the endpoint as last value and directing points between start and endpoint.
required Arg: <fraction>: The fraction between 0 and 1.
Example: point = curve( pointArray , 0.75 );
=============*/

curve( p , f )
{
	// y(t) = sum( binom( n , i ) * p[i] * ( t^i * ( ( 1 - t )^( n - i ) ) ) )

	n = p.size - 1;
	vec = ( 0 , 0 , 0 );

	for( i = 0 ; i < p.size ; i++ )
	{
		vec += vectorScale( p[i] , binom( n , i ) * power( f , i ) * power( ( 1 - f ) , ( n - i ) ) );
	}

	return vec;
}

power( value , power )
{
	result = 1;

	for( i = 0 ; i < power ; i++ )
	{
		result = result * value;
	}

	return result;
}

binom( n , k )
{
	binom = 1;

	if( n <  0 || n > 100 || k < 0 || k > n ) 
		return -1;

	if( k == 0 || k == n ) 
		return 1;

	for( i = 1 ; i <= k ; i++ )
	{
		binom *= ( ( n - i + 1 ) / i );
	}

	return binom;
}

vectorScale( v , s )
{
	return ( v[0] * s , v[1] * s , v[2] * s );
}

credits goes to extreme, i just rewrote their parts

to explain it a bit more:
this function interpolates between an array of points an gives you the coordinates to a specific fraction of your curve: (sorry it was fast-paintned :D)

Yes, great with fast paintned ;D.

I'll try this...

Thx.

Heuum I'm maybe a noob but where I had to put this script? in may plane.gsc or another one?

This is my plane.gsc:

main()
 {
 level thread planes();

 }
 planes() 

{
 level.PlaneSpeed = 3.5; 

stuka1 = getent ("stuka1","targetname"); 

temp = getent (stuka1.target,"targetname"); stuka1.dest = temp.origin; 
stuka1.start = stuka1.origin; 
stuka1 hide(); 

wait 2;

 while (1) 

{
 stuka1 thread plane_flyby("stuka_flyby");

wait 60;
 }
 }
 plane_flyby(sound) { // If you specified a sound to play then play it 
if (isdefined (sound)) 
self playsound (sound); 

wait 15; 

self show(); 

self moveto(self.dest, level.PlaneSpeed, 0.1, 0.1); 

wait level.PlaneSpeed; 

self hide(); 
self.origin = self.start; }

Mate, can you draw me small picture to show me how you want your plane to move? I guess this wouldn't require this complex maths then..

Yea thanks m8!

pseudo code (the way I would make this..):

time = 5.0;

plane moveTo( pointA , time ); //plane moves to the starting point of your curve

wait( time - 0.1 ); //wait a bit shorter to prevent a small delay of the movement

plane moveCirclular( 1024 , 180 , 3.0 , "left" ); //move on a bent line

plane moveTo( endPoint , time ); //move to the endpoint

wait( time - 0.1 );
//finish
plane delete();

moveCirclular():

moveCirclular( radius , degrees , time , direction )
{
	center = self.origin;
	right = anglesToRight( self.angles );
	right = ( right[0] * radius , right[1] * radius , right[2] * radius );

	if( !isDefined( direction ) || direction == "right" )
		center += right;
	else
		center -= right;

	linker = spawn( "script_model" , center );

	self linkTo( linker );

	linker rotateYaw( degrees , time );

	wait( time - 0.1 );

	self unlink();

	linker delete();
}

hope this will work