MODS Network

Registered Users: 130,362 Users Online: 81

"Valve got its start through the support and community mindedness of id [Software]. So if it hadn't been for [them]"..."Valve wouldn't have gotten its start. - Newell" *

Members Online

0 Active | 81 Guests

Online:

LATEST FORUM THREADS

by supersword

Posts: 2 / 88

The Future of MODSonline

In The News

by KAZAM3766

Posts: 1 / 479

CoD: Battle Royale

CoD+UO Map + Mod Releases

by morgawr

Posts: 1 / 2550

Damaged .pk3's

CoD Mapping

by lazygit

Posts: 1 / 3070

heli to attack ai

CoD4 SP Mapping

by DrBiggzz

Posts: 11 / 980

New Cod UO Rifle Mod.

CoD Mapping

Polls

-- see more --

Forums

Welcome to the MODSonline.com forums. Looking for Frequently Asked Questions? Check out our FAQs section or search it out using the SEARCH link below. If you are new here, you may want to check out our rules and this great user's guide to the forums and the website.
For more mapping and modding information, see our Wiki: MODSonWiki.com

Jump To:

Forum:	All Forums : Call of Duty
Category:	CoDUO Mapping CoD United Offensive mapping and level design.
Moderators:	foyleman, Foxhound, Mystic, StrYdeR, batistablr, Welshy, DrBiggzz, supersword

Author

Topic: random teleport locations

BA_GomerPyle

General Member
Since: Jul 26, 2012
Posts: 44
Last: May 18, 2019
[view latest posts]

Category: CoDUO Mapping Posted: Monday, Oct. 15, 2012 08:37 pm
Would it be possible to change this script so a player is transported to random locations? For instance. Could the line entTarget = getent(self.target, "targetname"); be changed to entTarget = getentarray(self.target, "targetname"); and would it work in multiplayer? main() { entTransporter = getentarray("enter","targetname"); if(isdefined(entTransporter)) { for(lp=0 ; lp < entTransporter.size ; lp++) { entTransporter[lp] thread Transporter(); } } } Transporter() { while(true) { self waittill("trigger",other); entTarget = getent(self.target, "targetname"); wait(0.10); other setorigin(entTarget.origin); other setplayerangles(entTarget.angles); //iprintlnbold ("You have been teleported !!!"); wait(0.10); } }
Share \|

serthy

General Member
Since: Sep 8, 2010
Posts: 482
Last: Jun 28, 2013
[view latest posts]

Category: CoDUO Mapping
Posted: Tuesday, Oct. 16, 2012 10:00 am

teleports you to different "target" positions:

Code:

main()
{
	level.transporter_entries = getEntArray( "enter" , "targetname" );
	level.transporters_targets = getEntArray( "target" , "targetname" );

	if( isDefined( level.transporter_entries ) && isDefined( level.transporters_targets ) && level.transporters_targets.size )
	{
		for( i = 0 ; i < level.transporter_entries.size ; i++ )
		{
			if( isDefined( level.transporter_entries[i] ) )
				level.transporter_entries[i] thread TransporterThink();
		}
	}
	else
	{
		iPrintLn( "No entries or targets found!" );
	}

}


TransporterThink()
{
	while( isdefined( self ) )
	{
		self waittill( "trigger" , player );

		target = level.transporters_targets[randomInt( level.transporters_targets.size )];

		player setOrigin( target.origin );
		player setPlayerAngles( target.angles );
		player iPrintLnBold( "WHOOOOOOOSHH" );
	}
}

teleports you to different deathmatch-spawns:

Code:

main()
{

	transporters = getEntArray( "enter" , "targetname" );

	if( isDefined( transporters ) )
	{
		for( i = 0 ; i < transporters.size ; i++ )
		{
			if( isDefined( transporters[i] ) )
				transporters[i] thread TransporterThink();
		}
	}

}


TransporterThink()
{
	while( isdefined( self ) )
	{
		self waittill( "trigger" , player );

		targets = getEntArray( "mp_dm_spawn" , "classname" );

		if( !isDefined( targets ) || !targets.size )
		{
			player iPrintLn( "No random target found!" );
			continue;
		}

		target = targets[randomInt( targets.size )];

		player setOrigin( target.origin );
		player setPlayerAngles( target.angles );
		player iPrintLnBold( "WHOOOOOOOSHH" );
	}
}