I have followed this tutorial step by step .
http://modsonline.com/Tutorials-read-658.html

and when i compile my ff it says that "rawfile,mapsmp_utility.gsc"
is missing and when i put it in the rawfile it says in the ff compile that could not open it
help ( my map is sp )

This is not urgent but i could use some help. Id like your help in that forum http://modsonline.com/Forums-top-163335.html rather than this one right now.

SPi writes...

In the tutorial, there is a syntax (spelling) error:

The tutorial has this:

self mapsmp_utility::triggerOn();

When it should be this:

self maps/mp/_utility::triggerOn(); //<--- note the slash "/" after each folder 

will there be any issue if my map is singleplayer??

is this right becouse i get bad syntax in one of these lines we talked about

main()
{
	thread player_closing_doors();
}

player_closing_doors()
{
	doors = getentarray("door_trig1","targetname");
	for(i=0; i<doors.size; i++)
	{
		doors[i] thread door_think();
	}
}

door_think()
{
   self.doormoving = false;
   self.doorclosed = true;
   self.doormodel = getent(self.target, "targetname");

	while(1)
	{
		self waittill("trigger");
		if(!self.doormoving)
		{
			self thread door_move();
		}
   }
}

door_move()
{
	self.doormoving = true;
	if(self.doorclosed)
	{
		self maps/mp/_utility::triggerOff();
		self.doormodel playsound("metal_open");
		self.doormodel rotateyaw(self.count, 2, 0.5, 0.5);
		self.doormodel waittill("rotatedone");
		self maps/mp/_utility::triggerOn();
		self.doorclosed = false;
	}
	else
	{
		self maps/mp/_utility::triggerOff();
		self.doormodel playsound("metal_close");
		self.doormodel rotateyaw((self.count * -1), 2, 0.5, 0.5);
		self.doormodel waittill("rotatedone");
		self maps/mp/_utility::triggerOn();
		self.doorclosed = true;
	}
	self.doormoving = false;
}

try this - I copied the functions from maps\mp\_utility.gsc to the foot of the code:

main()
{
	thread player_closing_doors();
}

player_closing_doors()
{
	doors = getentarray("door_trig1","targetname");
	for(i=0; i<doors.size; i++)
	{
		doors[i] thread door_think();
	}
}

door_think()
{
   self.doormoving = false;
   self.doorclosed = true;
   self.doormodel = getent(self.target, "targetname");

	while(1)
	{
		self waittill("trigger");
		if(!self.doormoving)
		{
			self thread door_move();
		}
	}
}

door_move()
{
	self.doormoving = true;
	if(self.doorclosed)
	{
		self triggerOff();
		self.doormodel playsound("metal_open");
		self.doormodel rotateyaw(self.count, 2, 0.5, 0.5);
		self.doormodel waittill("rotatedone");
		self triggerOn();
		self.doorclosed = false;
	}
	else
	{
		self triggerOff();
		self.doormodel playsound("metal_close");
		self.doormodel rotateyaw((self.count * -1), 2, 0.5, 0.5);
		self.doormodel waittill("rotatedone");
		self triggerOn();
		self.doorclosed = true;
	}
	self.doormoving = false;
}

triggerOff()
{
	if (!isdefined (self.realOrigin))
		self.realOrigin = self.origin;

	if (self.origin == self.realorigin)
		self.origin += (0, 0, -10000);
}

triggerOn()
{
	if (isDefined (self.realOrigin) )
		self.origin = self.realOrigin;
}

Thank you so much that was very importand Thank you again :D

A last question is there any way of making more than one doors usable?

3 specificly but each one open of its own.(not open all together)

I managed this out