Hello,

I want to create command which works same way as quickchat ones work. So there aren't any for loops and it works only if you're logged with rcon. Any ideas?

Regards,
z0d

a little confused on what you mean. could you elaborate more on that? maybe just give a quick example what you mean?

well, I want to send some server informations to website (like player's weapon, score, deaths etc.etc.). to do so, i must create cvar which shows me weapon/score/deaths value. that way, i must create a for loop which changes cvar's value every second but i dont want to use for loop. so i thought i could avoid server loop if i make some quickchat 'command' which calls my function that updates cvar... since only rcon users will be able to get response of that value (cvar value), it doesn't really matter if other users (those who are not logged with rcon) will be able to call quickchat function since nothing will happen (they wont even notice) but to make it look better, id like to make some rcon command f.e. /rcon updateserverinfo and that way it will call function which updates cvars. so basically, command which works same way as quickchat commands work (no for loops or anything).

so for your website to read these stats you would need your website to be able to read a file from your servers FTP. thats the only way i see it correct? in that case you have alot of work ahead of you to make this command. its easy to make the cvar but when you do that you need to gather everyone in the server and list them on a file and have there stats next to there name indvidualy. then not only that you need your website to go into this file and organize the stats and display it on your website. and yes its possible but thats alotttttt of work that im sorry i dont have time to help you with. but hopefully someone on this site can.

nop, not really. might work that way but i connected to server using udp protocol. so it works way how 'console' works when u make homemade LAN/internet server.

well, here's sample i just made:

playerinfo()
{
		players = getentarray("player", "classname");
		
		for(i = 0; i < players.size; i++)
		{
			player = players[i];
	
			player_name = player.name;
			player_position = player.origin;
			player_angle = player.angle;
			player_health = player.health;
			player_score = player.score;
			player_deaths = player.deaths;
      
			infoplayer = player_position + "/"...;
                        
                        setcvar("serverinfo123", infoplayer);

			wait 0.1;
                 }
}

so as i explained before, thats what i want my command (rcon) to do. so just go through this function every time i call it.

edited on Jul. 3, 2012 11:32 am by z0d

I might be wrong, since I'm not well-experienced, but I think you will still need a loop which would check if there's some update need to be done. As far as I know, you can't create and use rcon commands like /rcon updatestatus, I think you need to sign a value, like /rcon updatestatus 1. And because of that, you will need a loop that checks if 'updatestatus' var was changed. Can someone correct me if I'm wrong?

your exactly right just make sure in your code you change it back to 0 after you assign it to 1, so it dosnt keep updating when you dont want it to.

why do you want not to use a loop?

you can do it without as you said with the quickchat-system

have a search here in the forums + dowload sections there was a guy iirc named nebulak who created a kind of ingame quickchat rcon tool

it locks you in as admin and maybe if you use it this way, lets say V + 5 + 1 > and send a response to your _menus.gsc
there you can check the menu and if it is your admin quickmenu and your are an admin, you can update your player-info

this would require a clientside-mod (> download)
you can avoid that by lets say manually binding a button with:
"bind M menuresponse adminmenu saveplayerinfo"
and check in your _menus.gsc if the menu is "-1" and the response > and now send your information via your script

this is a workaround with no clientside script and no extra loop

you still might check if the player is an admin with for example

if( player getGuid() == level.adminGuids[i] ) player.is_admin = true;

this is something what i wrote and use (similar) in my mod:

init()
{
	level thread updatePlayerInformationLooped();
}

updatePlayerInformationLooped()
{
	// catch all players
	players = getEntArray( "player" , "classname" );

	// while game[state] != "intermission"
	for( nextToUpdate = 0 ; !isDefined( game["state"] ) || game["state"] != "intermission" ; nextToUpdate++ )
	{
		// a short waittime: would take here 6.4 seconds to catch all possible players
		wait( 0.1 );

		// if we updated all players, reset variables and get all players again
		if( nextToUpdate >= players.size )
		{
			players = getEntArray( "player" , "classname" );
			nextToUpdate = 0;
		}

		// if the current player is defined & a player, save his stats
		if( isDefined( players[nextToUpdate] ) && isPlayer( players[nextToUpdate] ) )
		{
			// maybe check here if this player is allowed save his info
			// if( !players[nextToUpdate] isAdmin() )
			// 	continue;

			players[nextToUpdate] sendPlayerInfo();
		}
	}
	
	// if the game[state] is in intermission (scoreboard) then save again all stats
	level thread updatePlayerInformationSingle();
}

updatePlayerInformationSingle()
{
	players = getEntArray( "player" , "classname" );

	for( i = 0 ; i < players.size ; i++ )
	{
		wait( 0.1 );

		if( isDefined( players[i] ) && isPlayer( players[i] ) )
		{
			// maybe check here if this player is allowed save his info
			// if( !players[i] isAdmin() )
			// 	continue;

			players[i] sendPlayerInfo();
		}
	}
}

sendPlayerInfo()
{
	// seperate your inputs with this delimiter if parsing required on your website
	delim = "|";
	// define info as empty string
	info = "";

	// reset CVAR
	setCvar( "playerinfo" , info );

	// add all possible stats here
	data = [];
	data[data.size] = self.name;
	data[data.size] = self.origin;
	data[data.size] = self getGuid();
	data[data.size] = self getEntityNumber();
	data[data.size] = self.angles;
	data[data.size] = self getCurrentWeapon();
	data[data.size] = self.score;
	data[data.size] = self.deaths;
	
	// merge all information
	for( i = 0 ; i < data.size ; i++ )
	{
		if( isDefined( data[i] ) )
		{
			if( i == data.size - 1 )
				info += data[i];
			else
				info += ( data[i] + delim );
		}
	}

	// and send it this way to the server (remember the char limit is around 1000)
	setCvar( "playerinfo" , info );
}

im not really a for loop lover so... :P ill check it out, thanks :)