Hello everyone,

I have a problem with a script when I have too many players here a server bug in the Screen error.

Sorry for my English I am French: s

http://screenshot.xfire.com/s/117215962-4.jpg

up

So, what does that have to do with the topic's title ?
Do you have a radio script in your map/mod ? If so, what is it ?
You'll have to give some more info.

Are you constantly calling SetText() on a hud element?

Me Script :

ShowKDRatio()
{
if (isDefined(self.mc_kdratio))
self.mc_kdratio destroy();

wait .05;

self.mc_kdratio = newClientHudElem(self);
self.mc_kdratio.x = 7;
self.mc_kdratio.y = 180;
self.mc_kdratio.horzAlign = "left";
self.mc_kdratio.vertAlign = "top";
self.mc_kdratio.alignX = "left";
self.mc_kdratio.alignY = "middle";
self.mc_kdratio.alpha = 1;
self.mc_kdratio.fontScale = 1.4;
self.mc_kdratio.hidewheninmenu = true;
self.mc_kdratio.color = (.99, .99, .75);

for (;;)
{
text = "^2K\\D Ratio: ^10";

if (isDefined(self))
{
kills = self.pers["kills"];
deaths = self.pers["deaths"];

if (isDefined(kills) && isDefined(deaths))
{
if (deaths < 1)
deaths = 1;

if (kills < 1)
ratio = 0;
else
ratio = kills / deaths;

if (ratio >= 1)
text = "^2K\\D Ratio: " + ratio + " K: " + kills + " D: " + deaths;
else
text = "^2K\\D Ratio: ^1" + ratio + " K: " + kills + " D: " + deaths;
}
}

self.mc_kdratio setText( text );
wait 0.05;
}
}


sorry for the title I was wrong

Instead of calling SetText() every frame, try doing it just when player gets a kill / dies.

can you help me do this? it's a script I found on google. I do not see how it pls

Try using 3 huds with .label and setvalue() for each of them.

can you help me do this?

Just thread this on each player once and it'll last the whole game or until they leave match.

ShowKDRatio()
{
	self notify( "new_KDRRatio" );
	self endon( "new_KDRRatio" );
	self endon( "disconnect" );

	if( IsDefined( self.mc_kdratio ) )
	{
		self.mc_kdratio Destroy();
	}

	wait ( 0.05 );

	self.mc_kdratio = NewClientHudElem(self);
	self.mc_kdratio.x = 7;
	self.mc_kdratio.y = 180;
	self.mc_kdratio.horzAlign = "left";
	self.mc_kdratio.vertAlign = "top";
	self.mc_kdratio.alignX = "left";
	self.mc_kdratio.alignY = "middle";
	self.mc_kdratio.alpha = 1;
	self.mc_kdratio.fontScale = 1.4;
	self.mc_kdratio.hidewheninmenu = true;
	self.mc_kdratio.color = (.99, .99, .75);
	self.mc_kdratio.label = "^2K\\D Ratio: ^1";

	while( true )
	{
		ratio = 0.0;
		
		self waittill_either( "death", "killed_player" );

		kills = self.pers[ "kills" ];
		deaths = self.pers[ "deaths" ];

		if( IsDefined( kills ) && IsDefined( deaths ) )
		{
			if( deaths < 1 )
			{
				deaths = 1;
			}

			if( kills > 0 )
			{
				ratio = kills / deaths;
			}
		}
		
		self.mc_kdratio SetValue( ratio );

		wait ( 0.05 );
	}
}

waittill_either( msg1, msg2 )
{
	self endon( msg1 );
	self waittill( msg2 );
}