So does anybody happen toknow how to explain what this means?

level.mrc_firstaid = cvardef("mrc_firstaid",0,0,1,"int")

Ok so we are setting a global variable I figure but what is the array of values mean?

mrc_firstaid is the name right?
but whats 0
then 0
then 1
Ok type is int I get that.
Please if someone could explain this would be awesome!

check in one of the .gsc. you'll find what the cvardef(.....) handles

yes mrc_firstaid is the name of the cvar being set

default
min
max
type

If I remember correctly.

Duckster22 writes...

cvardef() is a custom function invented by a modder by the name of Ravir (Clifton Cline), who created Demolition gametype/mod for COD1. It's purpose is to parse a cvar according to its type (sting, int, or float), according to how it is to be executed for a map, or a gametype, or both. It sets a minimum, a maximum, and a default value:

cvardef( varname, vardefault, min, max, type )
{
	mapname = getcvar( "mapname" );

	gametype = getcvar( "g_gametype" );

	tempvar = varname + "_" + gametype;
	if( getcvar( tempvar ) != "" ) 
		varname = tempvar; 	

	tempvar = varname + "_" + mapname;
	if( getcvar( tempvar ) != "" )
		varname = tempvar;

	switch( type )
	{
		case "int":
			if( getcvar( varname ) == "" )
				definition = vardefault;
			else
				definition = getcvarint( varname );
			break;
		case "float":
			if( getcvar( varname ) == "" )
				definition = vardefault;
			else
				definition = getcvarfloat( varname );
			break;
		case "string":
		default:
			if( getcvar( varname ) == "" )
				definition = vardefault;
			else
				definition = getcvar( varname );
			break;
	}

	if( ( type == "int" || type == "float" ) && definition < min )
		definition = min;

	if( ( type == "int" || type == "float" ) && definition > max )
		definition = max;

	return definition;
}

edited on Aug. 23, 2011 02:36 pm by Tally

Awesome guys thanks for the help. I actually had basically just figured it out on my own when I checked and saw your replies so it awesome to have confirmed my suspicions.