MY doors dont work. i have a script file _door. ive made the door and origen brush into a brush model. ive put a trigger and put in targetname doortrig and ive connected the door with the trigger using W key. what do i do?

Do you want us to guess what your code looks like ?

Also, don't name the script "_door.gsc", it might interfere with other people's scripts. Better name it "mp_mapname_door.gsc".

_door.gsc

main()
{
thread scripted_door();
}
////////////////////////////////////////////////////////////
////////////////////////////////////////////////////////////
scripted_door()
{
doortrigger = getentarray("doortrig","targetname");
for(i=0;i<doortrigger.size;i++)
doortrigger [i] thread door_think();
}
///////////////////////////////////////////////////////////
///////////////////////////////////////////////////////////
door_think()
{
self.doormoving = false;
self.doorclosed = true;
self.doormodel = getent(self.target, "targetname");

while (1)
{
self waittill("trigger");
if(!self.doormoving)
self thread door_move();
}
}
////////////////////////////////////////////////////////////
////////////////////////////////////////////////////////////
door_move()
{
self.doormoving = true;
if(self.doorclosed)
{
self.doormodel rotateyaw(-90, 1, 0.5, 0.5);
self.doormodel waittill("rotatedone");
self.doorclosed = false;
}
else
{
self.doormodel rotateyaw(90, 1, 0.5, 0.5);
self.doormodel waittill("rotatedone");
self.doorclosed = true;
}
self.doormoving = false;
}

note that you name the door in this line
self.doormodel = getent(self.target, "targetname");

and here is a double sliding door

_sliders.gsc

main() 
{ 
    thread door_start(); 
} 

door_start() 
{ 
    doortrigger = getentarray("doortrig","targetname"); 
    for(i=0;i<doortrigger.size;i++) 
        doortrigger[i] thread door_think(); 
} 

door_think() 
{ 
    stuff = getentarray(self.target,"targetname"); 
    for(i=0;i<stuff.size;i++) 
    { 
        if(!isDefined(stuff[i].script_noteworthy)) 
            continue; 

        if(stuff[i].script_noteworthy == "g_left_door") 
            self.left_door = stuff[i]; 
        else if(stuff[i].script_noteworthy == "g_right_door") 
            self.right_door = stuff[i]; 
    } 
    self.doorMoving = false; 
    while (1) 
    { 
        self waittill("trigger"); 
        if(!self.doorMoving) 
            self thread door_move(); 
    } 
} 

door_move() 
{ 
    self.doorMoving = true; 
    self.right_door movey(31,2,0.5,0.5); 
    self.left_door moveY(-31,2,0.5,0.5); 
    wait 3.5; 
    self.right_door movey(-31,2,0.5,0.5); 
    self.left_door moveY(31,2,0.5,0.5); 
    wait 3.5; 
    self.doorMoving = false; 
}  

notice that the( script_noteworthy named g_left_door)
and ( script_noteworthy named g_right_door)

i uploaded attach file prefab of glass sliding doors for this sliders.gsc

attachment: application(2.3Kb) copy on notepad close and save as
sliders.map, as map file in prefabs folder