I'm trying to disable weapons for allies only in a particular area (an admin room) to stop camping. (This is for a zombie mod btw). I don't want to just use a weap clip because that is kinda lame. I've got two triggers one at the top of the ladder to the room, the one at the top disables weapons and the bottom one enables them.

Here is my current script:

//**** WEAPON DISABLING & ENABLING ****

weap_disabling()
{

	weap_disable = getent( "weap_disable", "targetname" );
	
	if(!isdefined(weap_disable))
	 {
	   self SetTeamForTrigger( game["allies"] );

	 }

    weap_disable waittill( "trigger", player );
	player disableweapons();
	player iPrintlnBold( "^1Weapons Disabled to stop Bad, BAD Camping!" );
	weap_disable maps\mp\_utility::triggerOff();
	wait 1;
	weap_disable maps\mp\_utility::triggerOn();

}
weap_enabling()
{	
	weap_enable = getent( "weap_enable", "targetname" );
	
	if(!isdefined(weap_enable))
	 {
	   self SetTeamForTrigger( game["allies"] );
	   
	 }
	
	weap_enable waittill( "trigger", player );
	player enableweapons();
	weap_enable maps\mp\_utility::triggerOff();
	wait 1;
	weap_enable maps\mp\_utility::triggerOn();

}
//**** END OF WEAPON DISABLING & ENABLING ****

Thanks for any help in advance :)

edited on Dec. 17, 2010 04:44 pm by POOTIS

Does the script not work?

Looks fine in principle, although you will need to stick both of the functions in a while loop to cover multiple activations of the trigger.

And you don't need to turn the trigger on / off as this may allow additional players to slip past the trigger.

Use a single trigger, covering the room or space. This script will stop the player using weapons in that trigger:

init()
{
	// handle disabled weapon check variable
	level thread onPlayerConnect();
	level thread setupTrigger();
}

onPlayerConnect()
{
	while(1)
	{
		level waittill( "connected", player );
		player thread onDeath();
		player.weaponsDisabled = false;
	}
}

onDeath()
{
	self endon( "disconnect" );
	
	while(1)
	{
		self waittill( "death" );
		self.weaponsDisabled = false;
	}
}

setupTrigger()
{
	weapon_disable = getEnt( "weap_disable", "targetname" );
	
	while(1)
	{
		weapon_disable waittill( "trigger", player );
	
		if( player.pers["team"] == "allies" && !player.weaponsDisabled )
		{
			player.weaponsDisabled = true;
			player thread disableWeapons( weapon_disable );
		}
	}
}

disableWeapons( trigger )
{
	self endon( "disconnect" );
	self endon( "death" );
	self endon( "joined_spectator" );
	self endon( "left_weapon_trigger" );
	
	self iPrintLnBold( "Weapons disabled" );
	self disableWeapons();
	
	while(1)
	{
		if( !self isTouching( trigger ) )
		{
			self iPrintLnBold( "Weapons enabled" );
			self enableWeapons();
			self.weaponsDisabled = true;
			self notify( "left_weapon_trigger" );
		}
		
		wait 0.05;
	}
}

Thank you for the script xylozi :)

EDIT: for some reason it is failing to work ingame, it just spams the player with 'weapons disabled' a lot of times and then displays 'weapons enabled' at the end of this spam. Weapons aren't actually disabled as well :P

edited on Dec. 20, 2010 10:31 am by POOTIS

Tested and fixed the code, this works perfectly now:

init()
{
	// handle disabled weapon check variable
	level thread onPlayerConnect();
	level thread setupTrigger();
}

onPlayerConnect()
{
	while(1)
	{
		level waittill( "connected", player );
		player thread onDeath();
		player.weaponsDisabled = false;
	}
}

onDeath()
{
	self endon( "disconnect" );
	
	while(1)
	{
		self waittill( "death" );
		self.weaponsDisabled = false;
	}
}

setupTrigger()
{
	weapon_disable = getEnt( "weap_disable", "targetname" );
	
	while(1)
	{
		weapon_disable waittill( "trigger", player );
	
		if( player.pers["team"] == "allies" && !player.weaponsDisabled )
		{
			player.weaponsDisabled = true;
			player thread disablePlayerWeapons( weapon_disable );
		}
	}
}

disablePlayerWeapons( trigger )
{
	self endon( "disconnect" );
	self endon( "death" );
	self endon( "joined_spectator" );
	self endon( "left_weapon_trigger" );
	
	self iPrintLnBold( "Weapons disabled" );
	self disableWeapons();
	
	while(1)
	{
		if( !self isTouching( trigger ) )
		{
			self iPrintLnBold( "Weapons enabled" );
			self enableWeapons();
			self.weaponsDisabled = false;
			self notify( "left_weapon_trigger" );
		}
		
		wait 0.05;
	}
}

Thank you so much :)