It works now, thanks!

And what is the difference between self showAlliedObjective(); and self thread showAlliedObjective(); ?

Pedro699 writes...

How could I do it then?

Leal writes...

The added "thread" means that you arent going to wait for the function to be completed to run the next one. Without the thread the function called would need to be completed to go onto next one.

Aha all right Thank you!

Hope Pedro is going to answer me to the other question.

The difference? Its the word 'thread'

This tells the script engine to start your function (which has an infinite loop) but to continue with what it was doing before. Before the calling function was waiting for your objective loop to end before continuing (and it never ended).

~~~~~~~~~

In order to track which icons are in use you need to add a custom icon handler. This might give you an idea:

// based on code from AWE

getFreeObjId()
{
	if(!isDefined(level.trackobjicons)) 
      createObjectivesArray();

	id = undefined;

	for(i = 15; i >= 4; i--)
	{
		if(level.trackobjicons[i] == 0)
		{
			level.trackobjicons[i] = 1;
			id = i;
			break;
		}
	}
	return id;
}

deleteObjective(objnum)
{
	if(!isDefined(level.trackobjicons)) 
      createObjectivesArray();

	if(level.trackobjicons[objnum] == 1)
	{
		objective_delete(objnum);
		level.trackobjicons[objnum] = 0;
	}
}

createObjectivesArray() // create an array of available icon ids
{
	if(!isDefined(level.trackobjicons)) 
      level.trackobjicons = [];

	for(i = 0; i <= 15; i++)
	{
		if(i < 4) 
         level.trackobjicons[i] = 1; // First 4 objectives are reserved for gametypes (e.g S&D)
		else 
         level.trackobjicons[i] = 0;
	}
}

//============================//

// Usage:

showAlliedObjective()
{
   self endon("disconnect");
   self endon("killed_player");
   self endon("spawned");
     
   if(isDefined(self.markerid))
      num = self.markerid;
   else
      num = getFreeObjId();
      
   if(num != undefined)
   {
      self thread watchfordeath();
      self thread watchfordisconnect();
   
      objective_add(num, "current", self.origin);
      
      self.markerid = num;
      
      while(1)
      {
         objective_position(num, self.origin);
         wait 0.3;
      }
	}
}

watchfordeath() 
{
   self endon("disconnect");
   
   self waittill("killed_player");
   
   if(isDefined(self.markerid))
      deleteObjective(self.markerid);
}

watchfordisconnect() 
{
   self endon("killed_player");
   
   self waittill("disconnect");
   
   if(isDefined(self.markerid))
      deleteObjective(self.markerid);
}

I'm not sure how well the disconnect handler will work - personally I would implement a watchdog to clean up un-used icons.

But as mentioned previously once there are more than 12 players in the server it will stop working (due to the 4 icons required for S&D). CoD4 / 5 used 4 icons but I think CoD2 uses less, so might be able to free up a couple more.

Well the server im looking to put the mod in has 64 slots... and it's normaly at 45/64. Then bad for the zombies to search the hunters.

I will try to make this script which replaces what i used with getentitynumber because you said it's bad.