DeekCiti writes...

The cc_control1 are triggers to trigger the cablecar from diferent points, but they are not moving along with the cablecar, i dont know how to do that.

And Yess, the cablecar1 is the only entity that moves. I'm working in another 1 but first I want solve this.

I'm not really sure what isn't working right. In your script, it should work fine, although I would add a wait time, so no other players can trigger the car WHILE the car is already in motion. I also added the play loop sound and stop loop sound, but I don't even know if they are valid commands for COD2.

cablecar1_function()
{
	cablecar1 = getent("cablecar1", "targetname");
	cc_control1 = getent("cc_control1", "targetname");
	
	while(1)
	{
		cc_control1 waittill("trigger");
		
		wait (1);		
		cablecar1 moveto((4732, -944, -714), 15);
		cablecar1 PlayLoopSound("wolf_cablecar");
		wait (15);	//wait for full move
		cablecar1 StopLoopSound("wolf_cablecar");

		
		cc_control1 waittill("trigger");
		
		wait (1);		
		cablecar1 moveto((3480, -944, -269), 15);
		cablecar1 PlayLoopSound("wolf_cablecar");
		wait (15);	//wait for full move
		cablecar1 StopLoopSound("wolf_cablecar");
	}
}

According to your script, the sound should already emit from the cable car. Just set the alias for the cable car to looping, so the cable car plays a looping sound. That should be it.

If it doesn't work, you may have to add an origin to the cable car. (See Below)

Ok, it seems that the loop thing is not working quiet good.
When the cablecar move the sound is just the starting all over, like the first 2 secs. of the sound and then when it stop the sound continue to play to the end of the original sound. And the ( wait(15); ) thing, it giving me errors and sysdump, so I've changed it for other code:

cablecar1_function()
{
	cablecar1 = getent("cablecar1", "targetname");
	cc_control1 = getent("cc_control1", "targetname");
	
	while(1)
	{
		cc_control1 waittill("trigger");
		
		wait(1);
		
		cablecar1 moveto((4732, -944, -714), 15);
		cablecar1 playLoopsound("wolf_cablecar");
                cablecar1 waittill("movedone");
                cablecar1 stopLoopsound("wolf_cablecar");

		cc_control1 waittill("trigger");
		
		wait(1);
		
		cablecar1 moveto((3480, -944, -269), 15);
		cablecar1 playLoopsound("wolf_cablecar");
                cablecar1 waittill("movedone");
                cablecar1 stopLoopsound("wolf_cablecar");
	}
}

If a remove the loop, the sound it doenst looks to travel with the cablecar., using it, the sound travel with it. I can activate it from the control and wait till reach the end and push again to call it back, and it sound comming close, so thats good, but when the cablecar stop, the sound still playing till reach the end of the original sound.
Do you have an idea whats going on?
And Not so sure about to use the otherway you say. with the origin.
Let me know more please!!!



edited on Feb. 4, 2010 06:57 pm by SgtCortes69us

Yeah, it means the sound is too long. Cut the sound down to about 1-2 seconds. Then it should work.

Also, the reason I didn't use waittill("movedone"); is because sometimes that doesn't wait, so that's why I put in the wait 15. If movedone works, then that's fine.




Sometimes, what I do is I create 3 sounds. One sound as a start sound, the cable car starts. One sound as a loop sound, the cable car is looping. One sound as a stop sound, the cable car is stopping.

So I take the long sound, cut it into 3 parts.

cablecar_start.wav
cablecar_loop.wav
cablecar_stop.wav

Then in script, you add each sound in it's place, to blend them all together.

If you are not sure how to cut this sound up, attach the cable car sound and I will cut it into 3 parts for you.

DeekCiti writes...
I like how that sound. I like your idea.
Here you can download it, and I really thank you for your help and time you're taking to do this.
http://cid-93f729939d90c351.skydrive.live.com/self.aspx/Public/cablecar.wav
I've try to upload using here in this forum attachments but it didnt allowed me to, for some reason. But anyway, you can take it from the link above.
And then, you tell me how to add them to the script and csv file.
Once again, thanks alot.

I don't know how you add custom sounds in COD2, but you do. So add all 3 sounds in the attachment. I zipped them.

Here is the edited script. You can edit it to fit your sounds from here, now that you see what I'm doing. Would be easier if I could test it, but I can't, only you can.

cablecar1_function()
{
	cablecar1 = getent("cablecar1", "targetname");
	cc_control1 = getent("cc_control1", "targetname");
	
	while(1)
	{
		cc_control1 waittill("trigger");
		
		wait(1);
		
		cablecar1 moveto((4732, -944, -714), 15);
		cablecar1 playsound("cc_start");
		wait(1);	//to overlap start and loop sounds
		cablecar1 playLoopsound("cc_loop");
		wait(13);	//for car to almost get to end point to stop loop sound
		cablecar1 playsound("cc_stop");
		wait(0.5);	//stop sound must play before loop sound stops
		cablecar1 stopLoopsound("cc_loop");
		cablecar1 waittill("movedone");

		cc_control1 waittill("trigger");
		
		wait(1);
		
		cablecar1 moveto((3480, -944, -269), 15);
		cablecar1 playsound("cc_start");
		wait(1);	//to overlap start and loop sounds
		cablecar1 playLoopsound("cc_loop");
		wait(13);	//for car to almost get to end point to stop loop sound
		cablecar1 playsound("cc_stop");
		wait(0.5);	//stop sound must play before loop sound stops
		cablecar1 stopLoopsound("cc_loop");
		cablecar1 waittill("movedone");
	}
}

Here is the edited Soundalias.

name,sequence,file,vol_min,vol_max,vol_mod,pitch_min,pitch_max,dist_min,dist_max,channel,type,probability,loop,masterslave,loadspec,subtitle,compression,secondaryaliasname,volumefalloffcurve,startdelay,speakermap,reverb,lfe percentage


#Ambiance,,,,,,,,,,,,,,,,,,,,,,,


ambient_mp_wolfenstein_castle,,ambient/amb_france01b.mp3,0.63,,,,,,,local,streamed,,looping,,mp_wolfenstein_castle,,,,,,,,



#Ambient Elements,,,,,,,,,,,,,,,,,,,,,,,


cc_start,,misc/cablecar_start.wav,0.85,0.95,element,0.8,1.2,7,800,auto,streamed,,,,mp_wolfenstein_castle,,,,,,,,
cc_loop,,misc/cablecar_loop.wav,0.85,0.95,element,0.8,1.2,7,800,auto,streamed,,looping,,mp_wolfenstein_castle,,,,,,,,
cc_stop,,misc/cablecar_stop.wav,0.85,0.95,element,0.8,1.2,7,800,auto,streamed,,,,mp_wolfenstein_castle,,,,,,,,



# Door sounds,,,,,,,,,,,,,,,


doorcreak,,misc/doorcreak.wav,1,1,foley,0.9,0.9,7,400,auto,,,,,mp_wolfenstein_castle
dooropening1,,misc/dooropening1.wav,1,1,foley,0.9,0.9,7,400,auto,streamed,,,,
doorclosing1,,misc/doorclosing1.wav,1,1,foley,0.9,0.9,7,400,auto,streamed,,,,
fermer_porte,,misc/fermer_porte.wav,1,1,foley,0.9,0.9,7,400,auto,streamed,,,,

I only edited the cable car part.

That should do it.

Thanks a lot budy, it works now just perfect..
Now I'll work with the other cablecar with the same stuff.
Once again, Thank you very much!!!