I've got a doorway that i'd like an actor to walk past, perform an animation, then vanish (going for a creepy style map). I've got an actor set up as a spawner with a targetname "ghost1" and a scripted node with the targetname "ghost1_look" where I want the animation to be performed. I keep getting a "Not an Actor" error when I try to run the level. I have a spawned patroller & a spawned dog working flawlessly but I can't seem to get this one to work. My code is below:

main gsc file:

#include maps\_utility;

#include maps\_anim;

#include common_scripts\utility;

#include animscripts\utility; 

#include maps\_patrol;

#using_animtree( "generic_human" );

main()

{

  maps\_load::main();
  maps\tunnel_fx::main();
  maps\createfx\tunnel_fx::main();
  maps\tunnel_anim::main();

  VisionSetNaked( "tunnel" );
  
  maps\_load::set_player_viewhand_model
  ( "viewhands_player_sas_woodland" );

  setExpFog(500, 3500, .1, .125, .14, 0);
  
  level.player takeallweapons();
  level.player giveWeapon( "m4_grunt" );
  level.player giveWeapon( "usp" );
  level.player giveWeapon( "flash_grenade" );
  level.player switchToWeapon( "m4_grunt" );

  patroller1 = getent( "patroller1", "targetname" );
  patroller1 thread add_spawn_function( maps\_patrol::patrol, self.target );

  thread doorghost1();

}


doorghost1()

{

  doorghost = getent("ghost1","targetname");
  doorghost.animname = "smoker";
  smokenode = getnode("ghost1_look","targetname");

  doorghost setgoalnode(smokenode);
  doorghost waittill("goal");
  smokenode anim_reach_solo(doorghost,"smoke_idle");
  smokenode anim_single_solo(doorghost,"smoke_idle");
  self delete(); 

}

anim gsc file:

#include maps\_utility;

#include maps\_anim;

#include common_scripts\utility;

#include animscripts\utility;


#using_animtree( "generic_human" );

main()

{

  level.scr_anim[ "smoker" ][ "smoke_idle" ] = %patrol_bored_idle_smoke;

  level.scr_anim[ "generic" ][ "patrol_walk" ]            = %patrol_bored_patrolwalk;
  level.scr_anim[ "generic" ][ "patrol_walk_twitch" ]     = %patrol_bored_patrolwalk_twitch;
  level.scr_anim[ "generic" ][ "patrol_stop" ]            = %patrol_bored_walk_2_bored;
  level.scr_anim[ "generic" ][ "patrol_start" ]           = %patrol_bored_2_walk;
  level.scr_anim[ "generic" ][ "patrol_turn180" ]         = %patrol_bored_2_walk_180turn;

  level.scr_anim[ "generic" ][ "patrol_idle_1" ]          = %patrol_bored_idle;
  level.scr_anim[ "generic" ][ "patrol_idle_2" ]          = %patrol_bored_idle_smoke;
  level.scr_anim[ "generic" ][ "patrol_idle_3" ]          = %patrol_bored_idle_cellphone;
  level.scr_anim[ "generic" ][ "patrol_idle_4" ]          = %patrol_bored_twitch_bug;
  level.scr_anim[ "generic" ][ "patrol_idle_5" ]          = %patrol_bored_twitch_checkphone;
  level.scr_anim[ "generic" ][ "patrol_idle_6" ]          = %patrol_bored_twitch_stretch;  

  level.scr_anim[ "generic" ][ "patrol_idle_smoke" ]      = %patrol_bored_idle_smoke;
  level.scr_anim[ "generic" ][ "patrol_idle_checkphone" ] = %patrol_bored_twitch_checkphone;
  level.scr_anim[ "generic" ][ "patrol_idle_stretch" ]    = %patrol_bored_twitch_stretch;

}

It's probably something simple that I've overlooked but I've tried everything I can think of. Any ideas?

Cheers!

Any ideas guys? I'm really struggling with this one.

doorghost = getent("ghost1","targetname");

Is that an actual AI or a spawner.

It's a spawner. I've set the actor up as a spawner (spawner check box) & linked a trigger_multiple to it to trigger it.

edited on May. 28, 2009 07:40 am by Tim451

A spawner is not an actor, remove the trigger and spawn an actor through the spawner with a script:

Use this: DoSpawn();

like so:

spawner = getEnt( "my_spawner", "targetname" );
myAI = spawner DoSpawn();

myAI will become the name of the spawner actor, you will use this name to call the AI in script so use myAI.

For example:

myAI.animname = 

He will not spawn if you can see him, if you want it to spawn even if you can see him then replace DoSpawn with StalingradSpawn.

edited on May. 28, 2009 08:57 am by jeannotvb

edited on May. 28, 2009 08:58 am by jeannotvb

Ok cheers for that, I've got him spawning now. How can I use the script to make him spawn only when I near the doorway? Currently he spawns, does his thing, then deletes before I get anywhere near it. I want the effect to be that when the player nears the doorway he moves into view, does his animation, then vanishes.

This is the "doorghost1" thread as it stands:

doorghost1()

{

  spawner = getent("ghost1","targetname");
  ghostspawn = spawner StalingradSpawn();
  ghostspawn.animname = "smoker";
  smokenode = getnode("ghost1_look","targetname");
  ghostspawn setgoalnode(smokenode);
  ghostspawn waittill("goal");
  smokenode anim_reach_solo(ghostspawn,"smoke_idle");
  smokenode anim_single_solo(ghostspawn,"smoke_idle");
  //ghostspawn delete(); 

}

I commented out the "ghostspawn delete();" line for now so I could ensure he was spawning correctly, which he is.

Cheers

edited on May. 28, 2009 10:29 am by Tim451

doorghost1()

{
  
  spawner = getent("ghost1","targetname");
  trig = getent("trig_ghost", "targetname);

  trig waittill("trigger)

  ghostspawn = spawner StalingradSpawn();
  ghostspawn.animname = "smoker";
  smokenode = getnode("ghost1_look","targetname");
  ghostspawn setgoalnode(smokenode);
  ghostspawn waittill("goal");
  smokenode anim_reach_solo(ghostspawn,"smoke_idle");
  smokenode anim_single_solo(ghostspawn,"smoke_idle");
  //ghostspawn delete(); 
}

So add a trigger (most likely a trigger_multiple) with a targetname of "trig_ghost".

Not sure if that will work as I have no knowledge of scripting

Works like a charm :)

Cheers guys